Přehled vlastností elementárních funkcí

Tomáš Kalvoda, KAM FIT ČVUT, 2014

Polynomy

Polynomem nazýváme libovolnou funkci f:ℝ->ℝ tvaru

f(x)=(∑_(k=0)^n)(Subscript[a, k])(x^k),x∈ℝ,

kde n∈ℕ a (Subscript[a, k])∈ℝ pro k=0,1,...,n. Stupněm polynomu nazýváme nejvyšší index k pro nějž (Subscript[a, k])≠0. Jako příklad uveďme

f(x)=4(x^3)-2x+5.

zde n=3, (Subscript[a, 3])=4, (Subscript[a, 2])=0, (Subscript[a, 1])=-2 a (Subscript[a, 0])=5. Stupeň tohoto polynomu je 3.

Manipulate[
Plot[
(x^k),{x,-3,3},
PlotRange->{-8,8},
PlotStyle->{Blue,Thick},
PlotLabel->"Grafy monomů",
AxesLabel->{Style["x",Italic,14],Style["(x^k)",Italic,14]},
ImageSize->400,
GridLines->Automatic,
GridLinesStyle->Directive[Gray,Dashed,Thin]
],
{{k,1,Style["k",Italic]},0,10,1,Appearance->"Labeled"}
]

Důležitým polynomem je polynom druhého stupně p(x)=a (x^2)+b x+c. Jeho kořeny (tj. hodnoty x∈ℝ pro něž p(x)=0) lze vyjádřit pomocí známého vzorce. Pokud je diskriminant D=(b^2)-4a c nezáporný, pak pro reálné kořeny platí

(Subscript[x, 1,2])=((-b±(Sqrt[D]))/(2a)).

Vrchol paraboly je v bodě o x souřadnici rovné -(b/(2a)). Tento je totiž průměrem kořenů (existují-li):

(((Subscript[x, 1])+(Subscript[x, 2]))/2)=((-b)/(2a)).

Manipulate[
Column[{
Style["D = "<>ToString[N[(b^2)-4a c,{∞,2}]],14,Italic],
Plot[a (x^2)+b x + c,{x,-10,10},
PlotRange->{-10,10},
PlotStyle->Blue,
ImageSize->400,
GridLines->Automatic,
GridLinesStyle->Directive[Gray,Dashed,Thin],
AxesLabel->{Style["x",Italic,14],Style["(ax^2)+bx+c",Italic,14]},
Epilog->{Switch[(b^2)-4a c≥0&&a≠0,True,{Red,Disk[{(1/(2a))(-b+(Sqrt[(b^2)-4a c])),0},.2],Disk[{(1/(2a))(-b-(Sqrt[(b^2)-4a c])),0},.2]},False,{}],Switch[a≠0,True,{Brown,Dashed,Line[{{((-b)/(2a)),-10},{((-b)/(2a)),10}}]},False,{}]}
]}],
{{a,-1,Style["a",Italic]},-10,10,.1,Appearance->"Labeled"},
{{b,3,Style["b",Italic]},-10,10,.1,Appearance->"Labeled"},
{{c,4,Style["c",Italic]},-10,10,.1,Appearance->"Labeled"}
]

Poznámka k hledání kořenů

Pro kořeny polynomů stupně 1,2,3,4 existují explicitní vzorce. Pro polynomy stupně 5 a výše už takovéto vzorce neexistují. Přesněji pomocí teorie grup lze dokázat, že vzorce pro kořeny polynomů stupně páteho a vyššího neexistují. Uvádíme přehled vzorců pro polynomy stupně 1 až 4.

coeffs={a,b,c,d,e};
poly[n_]:=Sum[coeffs[[k+1]](x^(n-k)),{k,0,n}]
For[n=1,n≤4,n++,
TraditionalForm[poly[n]==0]//Print;
Grid[{TraditionalForm[x]}/.Solve[poly[n]==0,x],Frame->All]//Print
]
Clear[poly,coeffs]

Ovšem pro polynom stupně 5 už Mathematica dává pouze přeformulování zadání:

Solve[a (x^5)+b (x^4)+c (x^3)+d (x^2)+e x + f==0,x]

Trigonometrické funkce

Shrneme definici a vlastnoti funkcí sinus, cosinus, tangens a kotangens (sin, cos, tg a cotg).

Sinus, kosinus a jednotková kružnice

Funkce sinus a kosinus lze snadno definovat pomocí jednotkové kružnice. V následující interaktivní demonstraci může uživatel pohybovat bodem na jednotkové kružnici a sledovat jak se mění hodnota funkce sinus nebo kosinus.

Připomeňme, že úhly měříme v obloukové míře pomocí radianů.

angle[x_,y_]:=Which[y≥0,Arg[x+I y],True,Arg[x+I y]+2π];
Manipulate[
LocatorPane[Dynamic[{xx,yy},({xx,yy}=((#)/(Sqrt[#.#])))&],
Row[{
(* kruznice *)
Dynamic[Show[
(* jednotkova kruznice a osy *)
Graphics[{
Circle[{0,0},1],
Arrow[{{-1.2,0},{1.2,0}}],
Arrow[{{0,-1.2},{0,1.2}}]
}],
(* trojuhelnik *)
Graphics[{
Line[{{0,0},{xx,0},{xx,yy},{0,0}}]
}],
(* uhel *)
Graphics[{Red,Circle[{0,0},.2,{0,angle[xx,yy]}],Text[Style["α",16],.3{Cos[angle[xx,yy]/2],Sin[angle[xx,yy]/2]}]
}],
(* zvyrazneni odvesny *)
Switch[func,
Sin[aa],Graphics[{
Blue,Line[{{xx,0},{xx,yy}}]
}],
Cos[aa],Graphics[{
Green,Line[{{0,0},{xx,0}}]
}]
],
ImageSize->250
]],
(* graf *)
Dynamic[Plot[
func/.aa->t,{t,0,2π},
ImageSize->400,
Frame->True,
FrameLabel->{Style["α",16],Style[func/.aa->α,16]},
PlotStyle->Black,
FrameTicks->{{0,π/2,π,3π/2,2π},Automatic,None,None},
GridLines->{{angle[xx,yy]},{func/.aa->angle[xx,yy]}},
GridLinesStyle->Directive[{Dashed}],
Epilog->{Switch[func,Sin[aa],Blue,Cos[aa],Green],Line[{{angle[xx,yy],0},{angle[xx,yy],func/.aa->angle[xx,yy]}}]}
]]
}],
(* vzhled locatoru *)
Appearance->Graphics[{Red,Disk[]},ImageSize->6]
],
(* volba sin/cos *)
{{func,Sin[aa],"Trigonometrická funkce:"},{Sin[aa]->TraditionalForm[Sin[α]],Cos[aa]->TraditionalForm[Cos[α]]}},
{{xx,(Sqrt[2])/2},ControlType->None},
{{yy,(Sqrt[2])/2},ControlType->None}
]

V demonstraci výše je možné pohybovat bodem na kružnici prostým tažením myši.

Sinus i kosinus jsou funkce s definičními obory (Subscript[D, sin])=(Subscript[D, cos])=ℝ a obory hodnot (Subscript[H, sin])=(Subscript[H, cos])=⟨-1,1⟩. Obě funkce jsou periodické s periodou T=2π. Sinus je funkce lichá a kosinus funkce sudá,

sin(-x)=-sin(x), cos(-x)=cos(x), x∈ℝ.

Vzhledem k definici pomocí jednotkové kružnice není překvapením, že podle Pythagorovy věty platí

(sin^2)(x)+(cos^2)(x)=1.

Vzorce pro dvojnásobný argument:

sin(2x)=2sin(x)cos(x),
cos(2x)=((cos(x))^2)-((sin(x))^2), x∈ℝ.

Součtové vzorce:

sin(x+y)=sin(x)cos(y)+cos(x)sin(y),
cos(x+y)=cos(x)cos(y)-sin(x)sin(y), x,y∈ℝ

Dále připomeňme význačné funkční hodnoty.

vals={0,π/6,π/4,π/3,π/2};
Grid[
{
Join[{" "},vals],
Join[{TraditionalForm[Sin[x]]},Sin/@vals],
Join[{TraditionalForm[Cos[x]]},Cos/@vals]
},
Frame->All,Spacings->{2,2}
]
Clear[vals]

Tangens a kotangens

Funkce tangens a kotangens jsou definovány vztahy

tg(x)=((sin(x))/(cos(x))), cotg(x)=((cos(x))/(sin(x))).

Vzhledem k vlastnostem funkcí sinus a kosinus platí (Subscript[D, tg])=ℝ–{(π/2)+k π|k∈ℤ}, (Subscript[D, cotg])=ℝ-{k π|k∈ℤ} a (Subscript[H, tg])=(Subscript[H, cotg])=ℝ.

Row[{
Plot[
Tan[x],{x,-3π/2,3π/2},
Exclusions->{-π/2,π/2},
Frame->True,
PlotStyle->Blue,
ImageSize->250,
FrameLabel->{Style["x",Italic,14],Style["tg(x)",Italic,14]},
FrameTicks->{{-3π/2,-π,-π/2,0,π/2,π,3π/2},None,None,None},
GridLinesStyle->Directive[{Dashed}],
GridLines->{{-3π/2,-π,-π/2,π/2,π,3π/2},None}
],,
Plot[
Cot[x],{x,-3π/2,3π/2},
Exclusions->{-π,0,π},
Frame->True,
PlotStyle->Red,
ImageSize->250,
FrameLabel->{Style["x",Italic,14],Style["cotg(x)",Italic,14]},
FrameTicks->{{-3π/2,-π,-π/2,0,π/2,π,3π/2},None,None,None},
GridLinesStyle->Directive[{Dashed}],
GridLines->{{-3π/2,-π,-π/2,π/2,π,3π/2},None}
]
}]

Významné funkční hodnoty jsou snadno odvoditelné z hodnot sinus a kosinus,

vals={π/6,π/4,π/3};
Grid[
{
Join[{" "},vals],
Join[{TraditionalForm[Tan[x]]},Tan/@vals],
Join[{TraditionalForm[Cot[x]]},Cot/@vals]
},
Frame->All,Spacings->{2,2}
]
Clear[vals]

Inverze některých zúžení

Zúžíme-li funkci sin na interval ⟨-π/2,π/2⟩ dostaneme prostou funkci jejíž inverzi nazýváme arkus sinus a značíme arcsin. Platí tedy

sin(arcsin(x))=x, x∈⟨-1,1⟩

a

arcsin(sin(x))=x, x∈(-π/2,π/2⟩.

Na grafu níže je modře vynesen sinus a červeně arkus sinus.

Show[
Plot[Sin[x],{x,-π/2,π/2},PlotRange->{-π/2,π/2},AspectRatio->1,Ticks->{{-π/2,-π/4,π/4,π/2},{-π/2,-π/4,π/4,π/2}},GridLines->Automatic,PlotStyle->{Blue,Thick},GridLinesStyle->Directive[Gray,Dashed,Thin],AxesLabel->{Style["x",Italic,12],Style["y",Italic,12]}],
Plot[ArcSin[x],{x,-1,1},PlotStyle->{Thick,Red}]
]

Zúžíme-li funkci cos na interval ⟨0,π⟩ dostaneme prostou funkci jejíž inverzi nazýváme arkus kosinus a značíme arccos. Platí tedy

cos(arccos(x))=x, x∈⟨-1,1⟩

a

arccos(sin(x))=x, x∈(0,π⟩.

Na grafu níže je modře vynesen sinus a červeně arkus sinus.

Show[
Plot[Cos[x],{x,0,π},PlotRange->{{-1,π},{-1,π}},AspectRatio->1,Ticks->{{-1,1,π/2,π},{-1,1,π/2,π}},GridLines->Automatic,PlotStyle->{Blue,Thick},GridLinesStyle->Directive[Gray,Dashed,Thin],AxesLabel->{Style["x",Italic,12],Style["y",Italic,12]}],
Plot[ArcCos[x],{x,-1,1},PlotStyle->{Thick,Red}]
]

Zúžíme-li funkci tangens na interval ⟨-π/2,π/2⟩ dostaneme prostou funkci jejíž inverzi nazýváme arkus tangens a značíme arctg. Platí tedy

tg(arctg(x))=x, x∈ℝ

a

arctg(tg(x))=x, x∈(-π/2,π/2⟩.

Na grafu níže je modře vynesen tangens a červeně arkus arkus tangens.

Show[
Plot[Tan[x],{x,-π/2,π/2},PlotRange->{{-4,4},{-π,π}},AspectRatio->1,
Ticks->{{-π/2,-π/4,π/4,π/2},{-π/2,-1,1,π/2}},
GridLines->{{-π/2,-π/4,π/4,π/2},{-π/2,-1,1,π/2}},
GridLinesStyle->Directive[Gray,Dashed,Thin],
PlotStyle->{Blue,Thick},
AxesLabel->{Style["x",Italic,12],Style["y",Italic,12]}],
Plot[ArcTan[x],{x,-4,4},PlotStyle->{Thick,Red}]
]

Exponenciální funkce

Funkci f(x)=(a^x), kde a>0 a x∈(Subscript[D, f])=ℝ nazýváme exponenciální funkcí o základu a. Oborem hodnot je množina (Subscript[H, f])=(0,+∞). Funkce f je rostoucí pro a>1 a klesající pro a<1. Pokud a=e (Eulerovo číslo), mluvíme zkrázeně o f jako o exponenciále.

Manipulate[
Plot[(a^x),{x,-4,4},
PlotRange->{0,5},
PlotStyle->Red,
ImageSize->400,
AxesLabel->{Style["x",Italic,14],Style["(a^x)",Italic,14]},
GridLines->Automatic,
GridLinesStyle->Directive[Gray,Dashed,Thin]
],
{{a,2,Style["a",Italic]},0.05,4,.05,Appearance->"Labeled"}
]

Pro a>0 platí

(a^x)(a^y)=(a^(x+y)), ((((a^x)))^y)=(a^(x·y)), (1/(a^x))=(a^(-x)), x,y∈ℝ.

Pro a≠1 je exponenciální funkce prostá a existuje tedy její inverzní funkce, kterou nazýváme logaritmem o základu a a značíme (Subscript[log, a]). Definičním oborem logaritmu je množina (0,+∞) a oborem hodnot je celé ℝ.

Manipulate[
Plot[
Log[a,x],{x,0,5},
PlotRange->{-5,5},
ImageSize->400,
PlotStyle->Blue,
GridLines->Automatic,
GridLinesStyle->Directive[Gray,Dashed,Thin],
AxesLabel->{Style["x",Italic,14],Style["(Subscript[log, a])(x)",Italic,14]}
],
{{a,10,Style["b",Italic]},.05,14,.1,Appearance->"Labeled"}
]

Analogicky platí vzorce

(Subscript[log, a])(x y)=(Subscript[log, a])(x)+(Subscript[log, a])(y), x,y>0,
 (Subscript[log, a])(a)=1, a>0,a≠1,
 (Subscript[log, a])((x^y))=y (Subscript[log, a])(x), x>0,y∈ℝ.

Hyperbolické funkce

S exponenciálou (e^x) úzce souvisí tzv. hyperbolické funkce sinus a kosinus. Jejich definice je jednoduchá.

sinh(x)=(1/2)((e^x)-(e^(-x))),
cosh(x)=(1/2)((e^x)+(e^(-x))).

Důvod proč jsou tyto funkce spojovány se sinem a kosinem leží v možnosti vyjádření obyčejného sinu a kosinu pomocí exponenciály komplexního argumentu.

Plot[
{Sinh[x],Cosh[x]},{x,-3,3},
PlotRange->{-3,3},
ImageSize->400,
PlotStyle->{Red,Blue},
AxesLabel->{Style["x",Italic,14]},
Epilog->{Text[Style["sinh(x)",Italic,14,Red],{-2.5,-2}],Text[Style["cosh(x)",Italic,14,Blue],{-2.5,2}]},
GridLines->Automatic,
GridLinesStyle->Directive[Gray,Dashed,Thin]
]